Project Sanitize - Dynamic Model

## INSTRUCTIONS

**Notes**

*[x] refers to the index number used to reference a particular cell (see Index in the Appendix). For example, [10] refers to Revenue. It is important to realize this is* ***not*** *the row, it is strictly an index number.*

*Absolute references to cells are in blue color font to indicate that they are only to be used as supplementary information. These absolute references may be incorrect if changes have been made to the model (i.e. a column or row has been added). Therefore, it is important to use the index located in the appendix.*

*Some of the explanations contain a “sample formula”. This is only to be used as a guide to follow along when reading the “translation” of the formula from Excel code to plain English. The specific cells that are referenced in the formula may have been adjusted since the creation of this report and therefore may be different from what is present in the current version of the model.*

## CONTROL PANEL

**How to Use the Model**

*The only cells that require the user’s input are located in the “control panel”. This is located in the top left corner of the model consisting of two columns and six rows. The first column contains the headers which this report will use to reference the cells in the second column which require user-input.*

**[1] Annual Data Sheet**

* Enter the name of the worksheet which contains the annual data for the company you are analyzing followed by “!$A$1”.
* Example, “AAPL\_ANNUAL!$A$1”

**[2] Quarterly Data Sheet**

* Enter the name of the worksheet which contains the quarterly data for the company you are analyzing followed by “!$A$1”.
* Example, “AAPL\_QUARTERLY!$A$1”

**[3] Data Starting Row**

* Enter the row number in which the data begins in the database
* Assuming the data feeder used to collect the data does not change, this should always be equal to 5

**[4] Data Starting Column**

* Enter the column number in which the data begins in the database
* Assuming the data feeder used to collect the data does not change, this should always be equal to 3

**[5] Number of Annual Periods**

* Enter the number of annual periods you would like to be included in the model
* This can range from 0 to the total number of periods in the database collected by the data feeder (Data validation will not allow the user to input a number greater than this)

**[6] Number of Quarterly Periods**

* Enter the number of quarterly periods you would like to be included in the model
* This can range from 0 to the total number of periods in the database collected by the data feeder (Data validation will not allow the user to input a number greater than this)

## INDEX CELLS:

*Located in the top right corner of the model, the following explanation begins with the first column and explains each cell as you move down the column until reaching the bottom. Then move to the cell at the top of the column to left of the first column and continue this down until reaching the bottom, continue moving over one column at a time until all the index cells have been covered.*

**[7] Not Applicable ($M$1)**

* This will be used when stub period calculations are not possible due to lack of sufficient annual & quarterly data
* Conditional formatting is set to white out cells with a light blue fill when they are equal to “Not Applicable” thereby allowing the user to focus on only the relevant data

**[8] Opening ($M$2)**

* This will used in the sub-heading for “Opening Balance”

**[9] Balance ($M$3)**

* This will be used in later formulas for the calculation and consolidation checks [77], [141], [170], [221]
* This is also used in the sub-heading for “Opening Balance”

**[10] Stub ($M$4)**

* This will be used in later formulas attached to the sub-headings (Current & Prior) for the stub period calculations, to create the sub-heading (Current Stub & Prior Stub)

**[11] LTM ($M$5)**

* This will be used in later formulas to create the sub-headings for the stub period calculations

**[12] Prior Fiscal ($M$6)**

* This will be used in later formulas to create the sub-headings for the stub period calculations

**[13] Current ($M$7)**

* This will be used in later formulas to create the sub-headings for the stub period calculations

**[14] Prior ($M$8)**

* This will be used in later formulas to create the sub-headings for the stub period calculations

**[15] Error ($M$9)**

* This will be used in later formulas for the calculation and consolidation checks [77], [141], [170], [221]

**[16] Total Number of Periods ($N$3)**

* [5] Number of Annual Periods + [6] Number of Quarterly Periods
* Equals the total number of periods that will be included in the model

**[17] 100 ($N$4)**

* Cell Value = 100
* Used in the calculation of the following 4 cells, which are used as a numerical placeholder for stub period calculation sub-headings (LTM, Prior Fiscal, Current Stub and Prior Stub). This will be explained in greater detail later in this document

**[18] LTM Place-marker ($N$5)**

* [Total number of periods] + [100]
* This will be used in later calculations to indicate that the model has reached the end of both annual and quarterly periods and should now start the stub period calculations. The output of this cell will be used to mark the column for **“LTM”**

**[19]** **Prior Fiscal Place-marker ($N$6)**

* [Total number of periods] + [100] + [1]
* This will be used in later calculations to indicate that the model has reached the end of both annual and quarterly periods and have already plotted the column for LTM, therefore the output of this cell will be used in later calculations as an indicator to mark the column for **“Prior Fiscal”,** the next piece in the stub period calculations

**[20]** **Current Stub Place-marker** **($N$7)**

* [Total number of periods] + [100] + [2]
* This will be used in later calculations to indicate that the model has reached the end of both annual and quarterly periods and has already plotted the column for LTM and Prior Fiscal, therefore the output of this cell will be used in later calculations as an indicator to mark the column for **“Current”**, the next piece in the stub period calculations

**[21]** **Prior Stub Place-marker** **($N$8)**

* [Total number of periods] + [100] + [3]
* This will be used in later calculations to indicate that the model has reached the end of both annual and quarterly periods and has already plotted the column for LTM, Prior Fiscal and Current, thus the output of this cell will be used in later calculations as an indicator to mark the column for **“Prior”**, the next piece in the stub period calculations

**[22] Number of Annual Periods in the Database ($O$3)**

* Counts the number of cells that are not blank in the database sheet for annual periods and then deducts 1 to remove the count of the row title, therefore leaving a number equal to the Total Number of Annual Periods in the Database. The number of annual periods entered (see [5] Number of Annual Periods) cannot exceed this limit.
* Sample Formula: COUNTA(OFFSET(INDIRECT($D$3),4,,1,1000))-1

**[23]** **Number of Quarterly Periods in the Database ($O$4)**

* Counts the number of cells that are not blank in the database sheet for quarterly periods and then deducts 1 to remove the count of the row title, therefore leaving a number equal to the Total Number of Quarterly Periods in the Database. The number of quarterly periods entered (see [6] Number of Quarterly Periods)cannot exceed this limit.
* Sample Formula: COUNTA(OFFSET(INDIRECT($D$4),4,,1,1000))-1

**[24]** **Row Number of [34] Actual Statements ($O$5)**

* Outputs the row number of [34] Actual Statements
* This is used in later offset functions to determine how many rows to shift down from [34] Actual Statements to extract the data from the appropriate row (i.e. this will be calculated by subtracting the value of this cell from the row number of the cell in question to determine how many rows to move down from [34] Actual Statements )

**[25]** **Column Number of Most Recent Quarter ($O$6)**

* [5] Number of Annual Periods + [6] Number of Quarterly Periods + 2
* Equals the column number of the most recent quarter (MRQ)
* This will be used in an offset function in later stub period calculations

**[26]** **Column Number One Year Prior to Most Recent Quarter ($O$7)**

* [Column number of the MRQ] – 4
* Equals the column number of the quarter that is one year (or 4 quarters) prior to the MRQ
* This will be used in later stub period calculations

**[27]** **Column Number of Last Period in Annual Database ($P$3)**

* [number of Annual Periods in the Database] + [Data Starting Column Number] – 1
* Equals the column number (in the database worksheet) of the last period in the annual database
* This is needed to extract the most recent data from the database which is found at the end of the database worksheet (further explained in “**[31] Column Number of First Annual Period Included in the Model “** cell explanation – see below)

**[28]** **Column Number of Last Period in Annual Database ($P$4)**

* [Number of Quarterly Periods in the Database) + (Data Starting Column Number) – 1
* Equals the column number of the last period in the quarterly database
* This is needed to extract the most recent data from the database which is found at the end of the database worksheet (further explained in “**[32] Column Number of First Quarterly Period Included in the Model”** cell explanation – see below)

**[29]** **Quarterly Indicator of the Most Recent Quarter ($P$6)**

* Equals the Quarterly Indicator of the MRQ
* This will be used in later stub period calculations
* Sample Formula: OFFSET($A$11,3,$O$6)

**[30]** **Column Number of the Most Recent Year ($P$7)**

* MATCH (Number of Annual Periods - 1, Row number of [34] Actual Statements : Row number of [34] Actual Statement ,0)
* Equals the column number of the Most Recent Year (MRY)
* This will be used in later stub period calculations

**[31]** **Column Number of First Annual Period Included in the Model ($Q$3)**

* [Column number of the Last Period in the Annual Database] – [Number of Annual Periods Being Included in the Model] – 1
* Equals the column number (in the database worksheet) of the first annual period that is included in the model
* This is where the model will begin pulling in the data from the annual database

**[32]** **Column Number of First Quarterly Period Included in the Model ($Q$4)**

* [Column number of the Last Period in the Quarterly Database] – [Number of Quarterly Periods Being Included in the Model] – [Number of Annual Periods Being Included in the Model]
* This will be used in later offset functions that will be used to determine which column to start pulling data from in the quarterly database (used in calculation to determine column number of the initial quarterly period)

**[33]** **Stub Period Calculation Check ($Q$6)**

* **Formula:** 
  + AND((Number of Quarterly Period) > (Quarterly Indicator +4), Number of Annual Periods >0)
* **Translation:**
  + This formula checks to see if BOTH of the following criteria are true:
  + (The Number of Quarterly periods) > (4 + Quarterly Indicator of MRQ)

AND

* + (The Number of Annual periods) > 0
* There criteria are necessary in order to complete the stub period calculations, therefore if either are not true, this cell will report “FALSE”, whereas if both are true, the cell will report “TRUE”
* This cell will be used in later calculations to determine if stub period calculations are possible and should proceed

## CORE MODEL

*Note: All formulas have been explained only once to avoid redundant explanations. Please refer to earlier explanations if needed.*

**[34] Actual Statements**

* This row is a critical row because it builds the frame (width) of the model based on what the user inputs in [5] Number of Annual Periods and [6] Number of Quarterly Periods.
* It is also used in later calculations to indicate how many columns to offset to the right in the database to extract the correct information (this will make more sense as we break down the formulations)
* Note: while it appears as though these cells contain either the text “ANNUAL” or “QUARTERLY” this is actually the result of conditional formatting. The true output of these cells are numerical values ranging from 0 to the *[the total number of periods – 1]*, which is then followed by the values which represent place markers for the stub period headings (more on this later)

**[34] Actual Statements (1st Column)**

* Contains the text “ACTUAL STATEMENTS”

**[34] Actual Statements (2nd Column)**

* Sample Formula:
  + IFERROR(IF($D$7="","",IF(0<$D$7,0,IF($D$8="","",IF(0<$N$3,0,"")))),"")
* Translation:
  1. If there is an error, leave the cell blank, otherwise continue with the formula
  2. Next, check if *[the number of annual periods being included in the model]* is blank, if true, then leave cell blank, otherwise continue with the formula
  3. Next, check if 0 < *[number of annual periods being included in the model]*, if true, then return 0 as the final output, otherwise continue with the formula
  4. Next, check if *[the number of quarterly periods being included in the model]* is blank, if true, then leave cell blank, otherwise continue with the formula
  5. Next, check if 0 < *[the total number of periods included in the model]*, if true, then return 0 as the final output, otherwise cell remains blank
* Explanation:
  + This cell determines whether or not the model should be built, if [5] Number of Annual Periods and [6] Number of Quarterly Periods are left blank, the model will not be built, otherwise this cell will be assigned a value of 0, which will mark the starting column for the first period of data

**[34] Actual Statements (3nd Column –> the Last Column of Model)**

* Sample Formula

=IFERROR(IF($D$7="","",IF(D11+1<$D$7,D11+1,IF($D$8="","",IF(D11+1<$N$3,D11+1,IF(D11<$N$5,$N$5,IF(D11<$N$6,$N$6,IF(D11<$N$7,$N$7,IF(D11<$N$8,$N$8,"")))))))),"")

* Translation:
  1. If there is an error, leave the cell blank, otherwise continue with the formula
  2. Next, check if *[the number of annual periods being included in the model]* is blank, if true, then leave cell blank, otherwise continue with the formula
  3. Next, check if *[the value of the previous cell in the row]+1* < *[the number of annual periods]*, if true, then return *[the value of the previous cell in the row] +1* as the final output, otherwise continue with the formula
  4. Next, check if *[the number of quarterly periods being included in the model]* is blank, if true, then leave cell blank, otherwise continue with the formula
  5. Next, check if *[the value of the previous cell in the row]+1* < *[the total number of periods being included; both annual & quarterly]*, if true, then return *[the value of the previous cell in the row] +1* as the final output, otherwise continue with the formula
  6. Next, check if *[the value of the previous cell in the row]* < *[the numeric place marker for LTM]*, if true, then the final output is equal to *[the numeric place marker for LTM]*, otherwise continue with the formula
  7. Next, check if *[the value of the previous cell in the row]* < *[the numeric place marker for Prior Fiscal]*, if true, then the final output is equal to *[the numeric place marker for Prior Fiscal]*, otherwise continue with the formula
  8. Next, check if *[the value of the previous cell in the row]* < *[the numeric place marker for Current Stub]*, if true, then the final output is equal to *[the numeric place marker for Current Stub]*, otherwise continue with the formula
  9. Next, check if *[the value of the previous cell in the row]* < *[the numeric place marker for Prior Stub]*, if true, then the final output is equal to *[the numeric place marker for Prior Stub]*, otherwise keep the cell blank

* Explanation:
  + The purpose of this formula is to increase the value reported in each cell, as you move from left to right, according to the user inputs for the [5] Number of Annual Periods & [6] Number of Quarterly Periods
  + Beginning with a value of 0 in the first column of the row, the value of each subsequent cell to the right will increase by 1 until it has reached a value of one less than the total number of periods (we deduct 1 because zero marks the place of the first period)
  + A value of [The total number of periods-1] marks the end of both annual and quarterly periods, therefore the formula then reports numbers greater than 100 that represent the place markers for the headings (LTM, Prior Fiscal, Current Stub and Prior Stub).

**[35]** **Consolidated Income Statement**

* This row pulls in the dates from the database for all the annual and quarterly periods
* Once the dates for all the annual and quarterly periods have been returned, the headings for LTM, Prior Fiscal, Current Stub and Prior Stub are returned
* Sample Formula:

=IF(D$11="","",IF(D$11-$N$3=100, $M$5,IF(D$11-$N$3=101, $M$6,IF(D$11-$N$3=102, $M$7,IF(D$11-$N$3=103, $M$8,IF(D$11<$D$7,OFFSET(INDIRECT($D$3),$A13-1,$Q$3+D$11),OFFSET(INDIRECT($D$4),$A13-1,$Q$4+D$11)))))))

* Translation:
  1. If *[the value in the cell in row [34] Actual Statements of the same column]* is blank, then the final output is blank, otherwise continue with the formula
  2. Next, check if *[the value in the cell in row [34] Actual Statements of the same column]* – *[the total number of periods] = 100*, then return the text “LTM” as the final output, otherwise continue with the formula
  3. Next, check if *[the value in the cell in row [34] Actual Statements of the same column]* – *[the total number of periods]* = 101, then return the text “Prior Fiscal” as the final output, otherwise continue with the formula
  4. Next, check if *[the value in the cell in row [34] Actual Statements of the same column]* – *[the total number of periods]* = 102, then return the text “Current” as the final output, otherwise continue with the formula
  5. Next, check if *[the value in the cell in row [34] Actual Statements of the same column]* – *[the total number of periods]* = 103, then return the text “Prior” as the final output, otherwise continue with the formula
  6. Next, check if *[the value in the cell in row [34] Actual Statements of the same column]* is less than *[the total number of annual periods]*, if true, then extract the data from the annual database from the row that has been input in the first column of the worksheet (column A) and the *[column number of initial annual period] + [the value in the cell in row [34] Actual Statements of the same column]* columns over and report that value
  7. Otherwise *[the value in row [34] Actual Statements of the same column]* is greater than *[the total number of annual periods],* indicating that you must now extract the data from the quarterly database from the row that has been input in the first column of the first sheet (column A) and the *[column number of initial quarterly period] + [the value of the cell in row [34] Actual Statements of the same column]* columns over and report that value
* Explanation:
  + The first IF statement determines whether the row should end (because *[the value of the cell in row [34] Actual Statements of the same column]* is blank, therefore indicating the end of the model)
  + The subsequent 4 IF statements are simply used to add the headings for the stub period calculations (LTM, Prior Fiscal, Current, Prior) once the model has reached the end of the annual periods and quarterly periods
  + The next part of the formula extracts the date from the Annual Database for all cells that have a value in row [34] Actual Statements that indicate it is an annual period (i.e. the value is less than what the user has input in [5] Number of Annual Period)
  + It then extracts the date from the Quarterly Database after the dates for all the annual periods have been returned

**[36] Indicator**

* This row pulls in the Quarterly Indicator for the respective period. For example, if the company year-end is on December 1st, the quarterly indicator that will be pulled in will be equal to 4
* The other component of this row is simply formatting for the headings for the stub period calculations (this is explained more as the formulation is broken down)
* Sample Formula:
  + =IF(D$11="","",IF(D13=$M$5,"-",IF(D13=$M$6,TEXT(OFFSET($A13,,MATCH($D$7-1,11:11,0)-1),"m/d/yyyy"),IF(D13=$M$7,$M$4,IF(D13=$M$8,$M$4,IF(D$11<$D$7,OFFSET(INDIRECT($D$3),$A14-1,$Q$3+D$11),OFFSET(INDIRECT($D$4),$A14-1,$Q$4+D$11)))))))
* Translation:

1. If *[the value of the cell in row [34] Actual Statements of the same column]* is blank, then the final output is blank, otherwise continue with the formula
2. Next, check if *[the value in the cell in row [35] Consolidated Income Statement of the same column]* equals “LTM”, if true, then return a dash (“-“) as the final output, otherwise continue with the formula
3. Next, check if *[the value in the cell in row [35] Consolidated Income Statement of the same column]* equals “Prior Fiscal”, if true, then return the date of the MRY by using the offset function to extract the value from the cell that is in *row [35] Consolidated Income Statement* and in the column of the MRY (the column number is determined by using the match function to find the column number in which the value in *row [34] Actual Statements*  is equal to *[the value of the total number of annual periods] - 1*
   1. If *[the value in the cell in row [35] Consolidated Income Statement of the same column]* does not equal “Prior Fiscal”, then continue with the formula
4. Next, check if *[the value in the cell in row [35] Consolidated Income Statement of the same column]* equals “Current”, if true, then return “Stub” as the final output, otherwise continue with the formula
5. Next, check if *[the value in the cell in row [35] Consolidated Income Statement of the same column]* equals “Prior”, if true, then return “Stub” as the final output, otherwise continue with the formula
6. Next, check if *[the value in the cell in row [34] Actual Statements of the same column]* is less than *[the total number of annual periods]*, if true, then extract the data from the Annual Database from the row that has been input in the first column of the worksheet (column A) and the *[column number of initial annual period] + [the value in the cell in row [34] Actual Statements of the same column]* columns over and report that value
7. Otherwise *[the value in row [34] Actual Statements of the same column]* is greater than *[the total number of annual periods],* indicating that you must now extract the data from the quarterly database from the row that has been input in the first column of the first sheet (column A) and the *[column number of initial quarterly period] + [the value of the cell in row [34] Actual Statements of the same column]* columns over and report that value

* Explanation:
  + The first IF statement determines whether the row should end (because *[the value of the cell in row [34] Actual Statements of the same column]* is blank, therefore indicating the end of the model)
  + The subsequent 4 IF statements are simply used to compliment the headings for the stub period calculations once the model has reached the end of both the annual and quarterly periods
  + “LTM” will be affixed with a dash ”-“
  + “Prior Fiscal” will be affixed with the date of MRY
  + “Current” will be affixed with the text “Stub” (Together creating the heading for “Current Stub”)
  + “Prior” will be affixed with the text “Stub” (Together creating the heading for “Prior Stub”)
  + The next part of the formula extracts the Quarterly Indicator from the Annual Database for all cells that have a value in *row [34] Actual Statements*  that indicates it is an annual period and then extracts the Quarterly indicator from the Quarterly Database after the indicators for all the annual periods have been returned

**[37] Operating Revenue**

* *Note: This formula is present in the majority of the cells in this model since its main purpose is to bring in the corresponding data from the database worksheets into this model.*
* This row pulls the data from the row number which is input in Column A (according to what data is required, e.g. Operating Revenue, Cost of Goods Sold etc.) from the appropriate database (Annual or Quarterly) which is indicated by the value present in *row [34] Actual Statements*
* Sample Formula:
  + =IF(D$11="","",IF(D$13=$M$5,CHOOSE($Q$6+1,$M$1,E17+F17-G17),IF(D$13=$M$6,CHOOSE($Q$6+1,$M$1,OFFSET($A17,,$P$7-1)),IF(D$13=$M$7,CHOOSE($Q$6+1,$M$1,SUM(OFFSET($A$11,$B17-$O$5,$O$6,1,-$P$6))),IF(D$13=$M$8,CHOOSE($Q$6+1,$M$1,SUM(OFFSET($A$11,$B17-$O$5,$O$7,1,-$P$6))),IF(D$11<$D$7,OFFSET(INDIRECT($D$3),$A17-1,$Q$3+D$11),OFFSET(INDIRECT($D$4),$A17-1,$Q$4+D$11)))))))
* Translation:
  + If *[the value in the cell in row [34] Actual Statements of the same column]* is blank, then the final output is blank, otherwise continue with the formula
  + Next, check if *[the value in the cell in row [35] Consolidated Income Statement* of the same column] equals “LTM”, if true, then:
    - Choose to return either *“Not Applicable”* or the formula *[Prior Fiscal + Current Stub – Prior Stub]*
      * If [33] Stub Period Calculation Check = TRUE, this means that the stub period calculations can proceed thus (TRUE = [1] + 1 = [2] = 2nd option in choose function = Sample Formula *[Prior Fiscal + Current Stub – Prior Stub]*
      * If [33] STUB PERIOD CALCULATION CHECK = FALSE, this means that the stub period calculations cannot be correctly calculated thus (FALSE = [0] +1 = [1] = 1st option = *“Not Applicable”*
        + A Conditional formatting rule is used to make cells containing *“Not Applicable”* shaded with a light blue fill, therefore whiting out the cells, indicating they are not relevant in this case
  + If the cell does not equal “LTM”, but instead equals “Prior Fiscal” then:
    - Choose to return either “Not Applicable” or the value of the MRY data in the same row
      * If [33] STUB PERIOD CALCULATION CHECK = TRUE, this means that the stub period calculations can proceed thus (TRUE = [1] + 1 = [2] = 2nd option in choose function = MRY data)
      * If [33] STUB PERIOD CALCULATION CHECK = FALSE, this means that the stub period calculations cannot be correctly calculated thus (FALSE = [0] +1 = [1] = 1st option = “Not Applicable”)
        + A Conditional formatting rule is used to make cells containing *“Not Applicable”* shaded with a light blue fill, therefore whiting out the cells, indicating they are not relevant in this case
  + If the cell instead equals “Current” then:
    - Choose to return either (“Not Applicable”) or the SUM of the cells that make up the current stub, which is determined by using an offset function which starts at the MRQ and selects the number of cells equal to the quarterly indicator of the MRQ
      * If [33] STUB PERIOD CALCULATION CHECK = TRUE, this means that the stub period calculations can proceed thus (TRUE = [1] + 1 = [2] = 2nd option in choose function = SUM of the cells that make up the current stub
      * If [33] STUB PERIOD CALCULATION CHECK = FALSE, this means that the stub period calculations cannot be correctly calculated thus (FALSE = [0] +1 = [1] = 1st option = “Not Applicable”)
        + A Conditional formatting rule is used to make cells containing *“Not Applicable”* shaded with a light blue fill, therefore whiting out the cells, indicating they are not relevant in this case
  + If the cell instead equals “Prior” then:
    - Choose to return either *“Not Applicable”* or the Sum of the cells that make up the prior stub, which is determined by using an offset function which sums the cells starting from 1 Year back from the MRQ and selects x number of cells to the left (x = the quarterly indicator of the MRQ)
      * If [33] STUB PERIOD CALCULATION CHECK = TRUE, this means that the stub period calculations can proceed thus (TRUE = [1] + 1 = [2] = 2nd option in choose function = SUM of the cells that make up the prior stub
      * If [33] STUB PERIOD CALCULATION CHECK = FALSE, this means that the stub period calculations cannot be correctly calculated thus (FALSE = [0] +1 = [1] = 1st option = “Not Applicable”)
        + A Conditional formatting rule is used to make cells containing *“Not Applicable”* shaded with a light blue fill, therefore whiting out the cells, indicating they are not relevant in this case
  + Next, check if *[the value in the cell in row [34] Actual Statements of the same column]* is less than *[the total number of annual periods]*, if true, then extract the data from the Annual Database from the row that has been input in the first column of the worksheet (column A) and the *[column number of initial annual period] + [the value in the cell in row [34] Actual Statements of the same column]* columns over and report that value
  + Otherwise *[the value in row [34] Actual Statements of the same column]* is greater than *[the total number of annual periods],* indicating that you must now extract the data from the quarterly database from the row that has been input in the first column of the first sheet (column A) and the *[column number of initial quarterly period] + [the value of the cell in row [34] Actual Statements of the same column]* columns over and report that value

**[77] Calculation Check**

Sample Formula:

* + =IF(D$13="","",IF(OR(D$13=$M$5,D$13=$M$6,D$13=$M$7,D$13=$M$8),"",IF(ABS(D$55-IF(D$11<$D$7,OFFSET(INDIRECT($D$3),$A55-1,$Q$3+D$11),OFFSET(INDIRECT($D$4),$A55-1,$Q$4+D$11)))<=$C$57,$M$3,$M$9)))

Translation:

1. If the cell in *row [35] Consolidated Income Statement* of the same column is blank, then the final output is blank, otherwise continue with the formula
2. Next, if the cell in *row [35] Consolidated Income Statement* of the same column is equal to either “LTM”, “Prior Fiscal”, “Current” OR “Prior”, then leave the cell blank, otherwise continue with the formula
3. Next, check if *the absolute value of [total net income from this worksheet] – [the total net income pulled from the data sheet]* is less than or equal to [1], if true, then the final output is “Balance”, otherwise the final output is “Error”

Explanation:

* The formula checks whether the Total Net Income calculated in the worksheet is roughly equal to the Total Net Income that is reported in the database (with a margin of error of +1 or -1)
* However, once it reaches the end of both the annual and quarterly periods, it returns blank cells for the columns involved in the stub period calculations

**[78] Foreign Sales**

Sample Formula:

=IF(D$11="","",IF(D$11<$D$7,OFFSET(INDIRECT($D$3),$A59-1,$Q$3+D$11),""))

Translation:

1. If *[the value in the cell in row [34] Actual Statements of the same column]* is blank, then the final output is blank, otherwise continue with the formula
2. Next, check if *[the value in the cell in row [34] Actual Statements of the same column]* is less than *[the number of annual periods]*, if true, then pull in the data from the annual database, otherwise leave the cell blank

Explanation:

* This row will pull in data from only the annual database and stop once the quarterly data begins

**[103] CONSOLIDATED BALANCE SHEET**

Sample Formula:

* =IF(D$11="","",IF(D$13=$M$5,$M$2,IF(OR(D$13=$M$6,D$13=$M$7,D$13=$M$8),"",D$13)))

Translation:

1. If *[the value in the cell in row [34] Actual Statements of the same column]* is blank, then the final output is blank, otherwise continue with the formula
2. If *[the cell in row [35] Consolidated Income Statement of the same column]* is equal to “LTM”, then return the text *“Opening”* as the final output, otherwise continue with the formula
3. Next, if *[the cell in row [35] Consolidated Income Statement of the same column]* is equal to either “Prior Fiscal”, “Current” OR “Prior”, then leave the cell blank, otherwise it returns the value of the cell in *row [35] Consolidated Income Statement* of the same column

**[104] INDICATOR**

Sample Formula:

* =IF(D$11="","",IF(D$89=$M$2,$M$3,IF(OR(D$13=$M$6,D$13=$M$7,D$13=$M$8),"",D$14)))

Translation:

* If *[the value in the cell in row [34] Actual Statements of the same column]* is blank, then the final output is blank, otherwise continue with the formula
* If *[the cell in the row above this one and the same column]* is equal to *“Opening”*, then return the text *“Balance”* as the final output, otherwise continue with the formula
* Next, if the cell in *row [35] Consolidated Income Statement* of the same column is equal to either “Prior Fiscal”, “Current” OR “Prior”, then leave the cell blank, otherwise return the value of the cell in *[36] Indicator* of the same column

**[141] Consolidation Check**

Sample Formula:

* =IF(D$13="","",IF(OR(D$13=$M$5,D$13=$M$6,D$13=$M$7,D$13=$M$8),"",IF(ABS(D$127-IF(D$11<$D$7,OFFSET(INDIRECT($D$3),$A127-1,$Q$3+D$11),OFFSET(INDIRECT($D$4),$A127-1,$Q$4+D$11)))<=$C$57,$M$3,$M$9)))

Translation:

1. If the cell in *row [35] Consolidated Income Statement* of the same column is blank, then the final output is blank, otherwise continue with the formula
2. Next, if the cell in *row [35] Consolidated Income Statement* of the same column is equal to either “LTM”, “Prior Fiscal”, “Current” OR “Prior”, then leave the cell blank, otherwise continue with the formula
3. Next, check if *the absolute value of [total assets from this worksheet] – [the total assets pulled from the data sheet]* is less than or equal to [1], if true, then the final output is “Balance”, otherwise the final output is “Error”

Explanation:

* The formula checks whether the Total Assets value calculated in the worksheet is roughly equal to the Total Assets value that is reported in the database (with a margin of error of +1 or -1)
* However, once it reaches the end of both the annual and quarterly periods, it returns blank cells for the columns involved in the stub period calculations

**[170] Consolidation Check**

Sample Formula:

* =IF(D$13="","",IF(OR(D$13=$M$5,D$13=$M$6,D$13=$M$7,D$13=$M$8),"",IF(ABS(D$158-IF(D$11<$D$7,OFFSET(INDIRECT($D$3),$A158-1,$Q$3+D$11),OFFSET(INDIRECT($D$4),$A158-1,$Q$4+D$11)))<=$C$57,$M$3,$M$9)))

Translation:

1. If the cell in *row [35] Consolidated Income Statement* of the same column is blank, then the final output is blank, otherwise continue with the formula
2. Next, if the cell in *row [35] Consolidated Income Statement* of the same column is equal to either “LTM”, “Prior Fiscal”, “Current” OR “Prior”, then leave the cell blank, otherwise continue with the formula
3. Next, check if *the absolute value of [total liabilities and stock equity from this worksheet] – [total liabilities and stock equity pulled from the data sheet]* is less than or equal to [1], if true, then the final output is “Balance”, otherwise the final output is “Error”

Explanation:

* The formula checks whether the Total Liabilities & Stock Equity value calculated in the worksheet is roughly equal to the Total Liabilities & Stock Equity value that is reported in the database (with a margin of error of +1 or -1)
* However, once it reaches the end of both the annual and quarterly periods, it returns blank cells for the columns involved in the stub period calculations

**[179] CONSOLIDATED CASH FLOW STATEMENT**

Sample Formula:

* =IF(D$11="","",D$13)

Explanation:

* If *[the value in the cell in row [34] Actual Statements of the same column]* is blank, then the final output is blank, otherwise return the value of the cell in *row [35] Consolidated Income Statement* of the same column

**[180] INDICATOR**

Sample Formula:

* =IF(D$11="","",D$14)

Explanation:

* If *[the value in the cell in row [34] Actual Statements of the same column]* is blank, then the final output is blank, otherwise return the value of the cell in *[36] Indicator* of the same column

**[221] Consolidation Check**

Sample Formula:

* =IF(D$173="","",IF(OR(D$13=$M$5,D$13=$M$6,D$13=$M$7,D$13=$M$8),"",IF(ABS(D$215-D$93)<=$C$217,$M$3,$M$9)))

Translation:

* If the cell in *row [179] CONSOLIDATED CASH FLOW STATEMENT* of the same column is blank, then the final output is blank, otherwise continue with the formula
* Next, if the cell in *row [35] Consolidated Income Statement* of the same column is equal to either “LTM”, “Prior Fiscal”, “Current” OR “Prior”, then leave the cell blank, otherwise continue with the formula
* Next, check if *[the absolute value of ([Cash End of Period] – [Cash & Equivalents from balance sheet])* is less than or equal to [1], if true, then the final output is “Balance”, otherwise the final output is “Error”

Explanation:

* The formula checks whether the Cash End of Period in the cash flow statement is roughly equal to the Cash & Equivalents value that is reported on the balance sheet (with a margin of error of +1 or -1)
* Once it reaches the end of both the annual and quarterly periods, it returns blank cells for the columns involved in the stub period calculations

**Appendix**

|  |  |
| --- | --- |
| **INDEX** | |
| [1] | Annual Data Sheet |
| [2] | Quarterly Data Sheet |
| [3] | Data Starting Row |
| [4] | Data Starting Column |
| [5] | Number Of Annual Periods |
| [6] | Number Of Quarterly Periods |
| [7] | Not Applicable |
| [8] | Opening |
| [9] | Balance |
| [10] | Stub |
| [11] | LTM |
| [12] | Prior Fiscal |
| [13] | Current |
| [14] | Prior |
| [15] | Error |
| [16] | Total Number of Periods |
| [17] | 100 |
| [18] | LTM Placeholder |
| [19] | Prior Fiscal Place-marker |
| [20] | Current Stub Place-marker |
| [21] | Prior Stub Place-marker |
| [22] | Number of Annual Periods in the Database |
| [23] | Number of Quarterly Periods in the Database |
| [24] | Row Number of [34] Actual Statements |
| [25] | Column Number of Most Recent Quarter |
| [26] | Column Number One Year Prior to Most Recent Quarter |
| [27] | Column Number of Last Period in Annual Database |
| [28] | Column Number of Last Period in Annual Database |
| [29] | Quarterly Indicator of the Most Recent Quarter |
| [30] | Column Number of the Most Recent Year |
| [31] | Column Number of First Annual Period Included in the Model |
| [32] | Column Number of First Quarterly Period Included in the Model |
| [33] | Stub Period Calculation Check |
| [34] | Actual Statements |
| [35] | Consolidated Income Statement |
| [36] | Indicator |
| [37] | Revenue |
| [38] | Operating Revenue |
| [39] | Adjustments to Revenue |
| [40] | Cost of Goods Sold |
| [41] | Cost of Goods Sold With Depreciation |
| [42] | Gross Operating Profit |
| [43] | SG&A + R&D Expense + Advertising |
| [44] | R&D Expense |
| [45] | SG&A Expenses |
| [46] | Advertising |
| [47] | Depreciation & Amortization Expense |
| [48] | Depreciation |
| [49] | Amortization |
| [50] | Amortization of Intangibles |
| [51] | Operating Profit After Depreciation |
| [52] | EBITDA |
| [53] | Non-Operating Income (Expense) |
| [54] | Interest Income |
| [55] | Earnings From Equity Interest |
| [56] | Other Income Net |
| [57] | Income, Acquired in Process R&A |
| [58] | Income, Restructuring And M&A |
| [59] | Other Special Charges |
| [60] | EBIT |
| [61] | Interest Expense |
| [62] | Pre-Tax Income |
| [63] | Income Taxes |
| [64] | Effective Tax Rate |
| [65] | After Tax Adjustments |
| [66] | Minority interest |
| [67] | Pref. securities of subsid. trust |
| [68] | Income Before Income Taxes |
| [69] | Net Income Continuing Operations |
| [70] | Net Income Discontinued Operations |
| [71] | Net Income Total Operations |
| [72] | Extraordinary Income/Losses |
| [73] | Income From Cum. Effect of Acct. Change |
| [74] | Income From Tax Loss Carryforward |
| [75] | Other Gains/Losses |
| [76] | Total Net Income |
| [77] | Calculation Check |
| [78] | Foreign Sales |
| [79] | Domestic Sales |
| [80] | Normalized Income |
| [81] | Net Income Available For Common |
| [82] | Diluted EPS: Dividends Paid per Share |
| [83] | Preferred Dividends |
| [84] | Excise Taxes |
| [85] | Basic EPS: Continuing Operations |
| [86] | Basic EPS: Discontinued Operations |
| [87] | Basic EPS: From Total Operations |
| [88] | Basic EPS: Extraordinary Items |
| [89] | Basic EPS: Cum. Effect of Acct. Change |
| [90] | Basic EPS: Tax Loss Carry Forward |
| [91] | Basic EPS: Other Gains/Losses |
| [92] | Basic EPS: Total |
| [93] | Basic EPS: Normalized |
| [94] | Diluted EPS: Continuing Operations |
| [95] | Diluted EPS: Discontinued Operations |
| [96] | Diluted EPS: From Total Operations |
| [97] | Diluted EPS: Extraordinary Items |
| [98] | Diluted EPS: Cum. Effect of Acct. Change |
| [99] | Diluted EPS: Tax Loss Carry Forward |
| [100] | Diluted EPS: Other Gains/Losses |
| [101] | Diluted EPS: Total |
| [102] | Diluted EPS: Normalized |
| [103] | CONSOLIDATED BALANCE SHEET |
| [104] | INDICATOR |
| [105] | Cash & Cash Equivalents (ST Inv.) |
| [106] | Cash & Equivalents |
| [107] | Restricted Cash |
| [108] | Marketable Securities |
| [109] | Receivables |
| [110] | Accounts Receivable |
| [111] | Loans Receivable |
| [112] | Other Receivable |
| [113] | Inventories |
| [114] | Inventories Raw Materials |
| [115] | Inventories Work in Progress |
| [116] | Inventories Purchased Components |
| [117] | Inventories Finished Goods |
| [118] | Inventories Other |
| [119] | Inventories Adjustments & Allowances |
| [120] | Other Current Assets |
| [121] | Prepaid Expenses |
| [122] | Current Deferred Income Taxes |
| [123] | Other Current Assets |
| [124] | Total Current Assets |
| [125] | Property, Plant & Equipment - Gross |
| [126] | Land And Improvements |
| [127] | Building And Improvements |
| [128] | Machinery, Furniture & Equipment |
| [129] | Construction in Progress |
| [130] | Other Fixed Assets |
| [131] | Accumulated Depreciation |
| [132] | Net Property, Plant & Equipment |
| [133] | Intangible Assets (Including Goodwill) |
| [134] | Intangibles |
| [135] | Cost in Excess |
| [136] | Other Non-Current Assets |
| [137] | Non-Current Deferred Income Taxes |
| [138] | Other Non-Current Assets |
| [139] | Total Non-Current Assets |
| [140] | Total Assets |
| [141] | Consolidation Check |
| [142] | Accounts Payable |
| [143] | Short Term Debt & Current Portion of LT Debt |
| [144] | Notes Payable |
| [145] | Short-Term Debt |
| [146] | Other Current Liabilities |
| [147] | Accrued Expenses |
| [148] | Accrued Liabilities |
| [149] | Deferred Revenues |
| [150] | Current Deferred Income Taxes |
| [151] | Other Current Liabilities |
| [152] | Total Current Liabilities |
| [153] | Long-Term Debt |
| [154] | Capital Lease Obligations |
| [155] | Deferred Income Taxes |
| [156] | Other Non-Current Liabilities |
| [157] | Minority Interest Liability |
| [158] | Total Non-Current Liabilities |
| [159] | Total Liabilities |
| [160] | Par + APIC - Treasury (& Other Adjustments) |
| [161] | Common Par |
| [162] | Additional Paid-In Capital |
| [163] | Cumulative Translation Adjustments |
| [164] | Treasury Stock |
| [165] | Other Equity Adjustments |
| [166] | Retained Earnings |
| [167] | Preferred Stock Equity |
| [168] | Total Equity |
| [169] | Total Liabilities & Stock Equity |
| [170] | Consolidation Check |
| [171] | Common Stock Equity |
| [172] | Total Capitalization |
| [173] | Preferred Shares |
| [174] | Ordinary Shares |
| [175] | Common Shares Out |
| [176] | Treasury Shares |
| [177] | Basic Weighted Shares |
| [178] | Diluted Weighted Shares |
| [179] | CONSOLIDATED CASH FLOW STATEMENT |
| [180] | INDICATOR |
| [181] | Net Income/Loss |
| [182] | Depreciation |
| [183] | Amortization |
| [184] | Amortization of Intangibles |
| [185] | Deferred Income Taxes |
| [186] | Operating Gains |
| [187] | Extraordinary Gains |
| [188] | Change in Receivables |
| [189] | Change in Inventories |
| [190] | Change in Prepaid Expenses |
| [191] | Change in Other Current Assets |
| [192] | Change in Payables |
| [193] | Change in Other Current Liabilities |
| [194] | Change in Other Working Capital |
| [195] | Other Non-Cash Items |
| [196] | Net Cash From Continuing Operations |
| [197] | Net Cash From Discontinued Operations |
| [198] | Net Cash From Total Operating Activities |
| [199] | Sale of Property, Plant & Equipment |
| [200] | Sale of Long-Term Investments |
| [201] | Sale of Short-Term Investments |
| [202] | Purchase of Property, Plant & Equipment |
| [203] | Acquisitions |
| [204] | Purchase of Long-Term Investments |
| [205] | Purchase of Short-Term Investments |
| [206] | Other Investing Changes, Net |
| [207] | Cash From Discontinued Investing Activities |
| [208] | Net Cash From Investing Activities |
| [209] | Issuance of Debt |
| [210] | Issuance of Capital Stock |
| [211] | Repayment of Long-Term Debt |
| [212] | Repurchase of Capital Stock |
| [213] | Payment of Cash Dividends |
| [214] | Other Financing Charges, Net |
| [215] | Cash From Discontinued Financing Activities |
| [216] | Net Cash From Financing Activities |
| [217] | Effect Exchange Rate Changes |
| [218] | Net Change in Cash & Equivalents |
| [219] | Cash At Beginning of Period |
| [220] | Cash End of Period |
| [221] | Consolidation Check |